分享一些自己觉得有用的东西。

其实我用的宏不多，授人以鱼不如授人以渔，会把每个命令的逻辑写清楚，你们可以拿模板去自己改。

/stopcasting

/cast 绝望祷言

主要说一下/stopcasting，这句的意思是打断当前施法，你可以把它加在任何你需要紧急释放的技能前面，比如绝望祷言，压制等等。

#showtooltip 真言术：障

/cast [@cursor] 真言术：障

直接在鼠标停留位置开罩子，不用点选。可以把技能改成任何需要点选施放位置的技能，比如暗影冲撞等等。

#showtooltip 暗影魔

/cast [harm][target=targettarget,harm] 暗影魔

如果目标是敌方则释放暗影魔，目标是友方对目标的目标释放暗影魔。一个减少目标切换频率的宏，心爆、慰、惩击都可以写这个宏，改技能名字就可以。摧心魔天赋通用，不用额外修改。

/cast [target=player] 闪光力场

对自身施法，推荐耐力也绑上，补耐的时候省去可能被卡视野的烦恼。（也可以绑灌注，嘻嘻）

#showtooltip 天堂之羽

/cast [mod,@cursor] [@player] 天堂之羽

/stopspelltarget

直接按脚下放羽毛，alt+按钮目标位置放羽毛。

#showtooltip

/cast [mod:alt,@player][noharm]纯净术;驱散魔法

双向整合宏，第一个技能改对友方技能，第二个对敌方技能，可以把两个技能绑在一个格子里。

#showtooltip

/cast [@mouseover,help] 痛苦压制

/cast [@target,help] 痛苦压制

/cast [@targettarget,help] 痛苦压制

/cast []痛苦压制

究级整合宏，目标是友方释放压制，目标是敌方对目标的目标释放压制。包含鼠标指向和框体指向，不用选中目标也可以释放技能。

#showtooltip

/cast [mod:alt,@player][]痛苦压制

另一个压制宏，目标是友方对目标释放，按住alt对自身释放，无需切换目标。

#showtooltip

/cast [talent:7/3]福音;[talent:7/2]灵魂护壳

第七层天赋整合宏，不用拖来拖去。

/cancelAura 晋升者之赐

取消晋升者之赐。

#showtooltip 沉默

/cast [target=focus,harm,exists] 沉默;[harm] 沉默; [target=targettarget, harm] 沉默

打断宏，有焦点优先焦点，无焦点对目标，目标友方对目标的目标。虽然戒律这版本已经没有打断了，这是以前的存货，但可以先留下。

#showtooltip 消散

/stopcasting

/cancelAura 消散

/cast 消散

按一下消散，再按取消消散，别多按。

/Click ExtraActionButton1

屏幕中间的按钮技能。

最后是鼠标指向宏，因为我自己是不用指向宏的，所以下面的东西我只是有但是并不常用（当然已经试验过了），如果实战有什么问题可以提出来。

/cast [@mouseover,help] 暗影愈合

/cast 暗影愈合

简单的治疗法术的指向宏。无论目标是敌方还是友方，优先对鼠标指向目标施法，无指向时则正常对当前友方目标施法。（团队框架指向有效，不用选中）

/cast [@mouseover,exists,help] [@target,exists,help] [@targettarget,exists,help] [@player]暗影愈合

复杂一点的治疗法术指向宏。优先对鼠标指向施法，无指向对当前友方目标施法，如果当前目标是敌人，对目标的目标施法，当前无目标对自身施法。（团队框架指向有效，不用选中）

#showtooltip 暗言术：痛

/cast [@mouseover,harm,nodead][harm,nodead] 暗言术：痛

简单的伤害法术指向宏。任何情况下都优先对鼠标指向施法。如无指向，则目标是敌方时对目标施法。

有任何问题欢迎留言，有用的话三连一下，谢谢各位！小狐鞠躬~